@echo off
chcp 936
setlocal
title 自动汉化程序
mode con cols=60 lines=25

IF NOT EXIST "%~dp0\release" goto notunzip

echo 正在从注册表寻找游戏安装路径...

:start
if "%PROCESSOR_ARCHITECTURE%"=="AMD64" (
set regpath=HKLM\SOFTWARE\WOW6432Node\Rockstar Games\Grand Theft Auto IV
) else (
set regpath=HKLM\SOFTWARE\Rockstar Games\Grand Theft Auto IV
)

for /f "skip=2 tokens=2*" %%a in ('reg query "%regpath%" /v InstallFolder') do set gamepath=%%b

if errorlevel 1 goto pathfail

if not "%gamepath%"=="" (
echo 获得的游戏安装路径是"%gamepath%"，正在安装汉化补丁...
cd /d "%~dp0\release"
xcopy /E /Y * "%gamepath%"
) else (
   goto pathfail
)

if errorlevel 1 (goto copyerror) else (goto done)

:pathfail
cls
color 04
echo ============================================================
echo 	无法找到游戏路径
echo 	请先正常启动一次游戏再试。或者手动复制补丁文件。
echo ============================================================
ping 127.1 -n 11 >nul
exit

:done
cls
color 02
echo ============================================================
echo 	完成!
echo 	你现在可以关闭该视窗
echo ============================================================
ping 127.1 -n 11 >nul
exit

:notunzip
cls
color 04
echo ============================================================
echo 	未找到汉化文件
echo 	请解压缩后再运行此脚本
echo ============================================================
ping 127.1 -n 11 >nul
exit

:copyerror
cls
color 04
echo ============================================================
echo 	复制补丁文件出错
echo	请手动放置汉化文件或是右键以系统管理员身分运行
echo ============================================================
ping 127.1 -n 11 >nul
exit
